| Server IP : 74.208.127.88 / Your IP : 18.221.100.57 Web Server : Apache/2.4.41 (Ubuntu) System : Linux ubuntu 5.4.0-163-generic #180-Ubuntu SMP Tue Sep 5 13:21:23 UTC 2023 x86_64 User : www-data ( 33) PHP Version : 7.4.3-4ubuntu2.29 Disable Function : pcntl_alarm,pcntl_fork,pcntl_waitpid,pcntl_wait,pcntl_wifexited,pcntl_wifstopped,pcntl_wifsignaled,pcntl_wifcontinued,pcntl_wexitstatus,pcntl_wtermsig,pcntl_wstopsig,pcntl_signal,pcntl_signal_get_handler,pcntl_signal_dispatch,pcntl_get_last_error,pcntl_strerror,pcntl_sigprocmask,pcntl_sigwaitinfo,pcntl_sigtimedwait,pcntl_exec,pcntl_getpriority,pcntl_setpriority,pcntl_async_signals,pcntl_unshare, MySQL : OFF | cURL : ON | WGET : ON | Perl : ON | Python : OFF | Sudo : ON | Pkexec : ON Directory : /proc/self/root/usr/share/doc/mawk/examples/ |
Upload File : |
#!/usr/bin/mawk -f
# qsort text files
#
function middle(x,y,z) #return middle of 3
{
if ( x <= y )
{ if ( z >= y ) return y
if ( z < x ) return x
return z
}
if ( z >= x ) return x
if ( z < y ) return y
return z
}
function isort(A , n, i, j, hold)
{
# if needed a sentinel at A[0] will be created
for( i = 2 ; i <= n ; i++)
{
hold = A[ j = i ]
while ( A[j-1] > hold )
{ j-- ; A[j+1] = A[j] }
A[j] = hold
}
}
# recursive quicksort
function qsort(A, left, right ,i , j, pivot, hold)
{
pivot = middle(A[left], A[int((left+right)/2)], A[right])
i = left
j = right
while ( i <= j )
{
while ( A[i] < pivot ) i++
while ( A[j] > pivot ) j--
if ( i <= j )
{ hold = A[i]
A[i++] = A[j]
A[j--] = hold
}
}
if ( j - left > BLOCK ) qsort(A,left,j)
if ( right - i > BLOCK ) qsort(A,i,right)
}
BEGIN { BLOCK = 5 }
{ line[NR] = $0 "" # sort as string
}
END {
if ( NR > BLOCK ) qsort(line, 1, NR)
isort(line, NR)
for(i = 1 ; i <= NR ; i++) print line[i]
}